r-concordexr: init

BioArchLinux/r-concordexr/PKGBUILD

@@ -0,0 +1,56 @@
+# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
+
+_pkgname=concordexR
+_pkgver=1.0.0
+pkgname=r-${_pkgname,,}
+pkgver=${_pkgver//-/.}
+pkgrel=1
+pkgdesc="Calculate the concordex coefficient"
+arch=(any)
+url="https://bioconductor.org/packages/${_pkgname}"
+license=(Artistic2.0)
+depends=(
+  r-biocparallel
+  r-cli
+  r-delayedarray
+  r-ggplot2
+  r-pheatmap
+  r-rlang
+  r-scales
+)
+checkdepends=(
+  r-biocneighbors
+  r-testthat
+  r-vdiffr
+)
+optdepends=(
+  r-biocneighbors
+  r-biocstyle
+  r-bluster
+  r-covr
+  r-knitr
+  r-patchwork
+  r-rmarkdown
+  r-scater
+  r-tenxpbmcdata
+  r-testthat
+  r-vdiffr
+)
+source=("https://bioconductor.org/packages/release/bioc/src/contrib/${_pkgname}_${_pkgver}.tar.gz")
+md5sums=('8a83636d355e3b226da6f6030c17d84d')
+sha256sums=('e3861fa72681a698376dc5555860a81fab3047fd64b7fc659ac5d3f5d850bcd8')
+
+build() {
+  mkdir -p build
+  R CMD INSTALL "$_pkgname" -l build
+}
+
+check() {
+  cd "$_pkgname/tests"
+  R_LIBS="$srcdir/build" NOT_CRAN=true Rscript --vanilla testthat.R
+}
+
+package() {
+  install -d "$pkgdir/usr/lib/R/library"
+  cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
+}

BioArchLinux/r-concordexr/lilac.py

@@ -0,0 +1,14 @@
+#!/usr/bin/env python3
+from lilaclib import *
+
+import os
+import sys
+sys.path.append(os.path.normpath(f'{__file__}/../../../lilac-extensions'))
+from lilac_r_utils import r_pre_build
+
+def pre_build():
+    r_pre_build(_G)
+
+def post_build():
+    git_pkgbuild_commit()
+    update_aur_repo()

BioArchLinux/r-concordexr/lilac.yaml

@@ -0,0 +1,22 @@
+build_prefix: extra-x86_64
+maintainers:
+- github: pekkarr
+  email: pekkarr@protonmail.com
+repo_depends:
+- r-biocparallel
+- r-cli
+- r-delayedarray
+- r-ggplot2
+- r-pheatmap
+- r-rlang
+- r-scales
+repo_makedepends:
+- r-biocneighbors
+- r-testthat
+- r-vdiffr
+update_on:
+- source: rpkgs
+  pkgname: concordexR
+  repo: bioc
+  md5: true
+- alias: r