r-flowgate: init

BioArchLinux/r-flowgate/PKGBUILD

@@ -0,0 +1,54 @@
+# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
+
+_pkgname=flowGate
+_pkgver=1.0.0
+pkgname=r-${_pkgname,,}
+pkgver=${_pkgver//-/.}
+pkgrel=1
+pkgdesc="Interactive Cytometry Gating in R"
+arch=(any)
+url="https://bioconductor.org/packages/${_pkgname}"
+license=(MIT)
+depends=(
+  r-biocmanager
+  r-dplyr
+  r-flowcore
+  r-flowworkspace
+  r-ggcyto
+  r-ggplot2
+  r-purrr
+  r-rlang
+  r-shiny
+  r-tibble
+)
+checkdepends=(
+  r-testthat
+)
+optdepends=(
+  r-knitr
+  r-rmarkdown
+  r-stringr
+  r-testthat
+  r-tidyverse
+)
+source=("https://bioconductor.org/packages/release/bioc/src/contrib/${_pkgname}_${_pkgver}.tar.gz")
+md5sums=('06253e3ee0f40cfd6446ec6aba2a4562')
+sha256sums=('6c21be074b5ce012c94b4595ce4328444666ff2ff0d177568273a1bdf2bf7572')
+
+build() {
+  mkdir -p build
+  R CMD INSTALL "$_pkgname" -l build
+}
+
+check() {
+  cd "$_pkgname/tests"
+  R_LIBS="$srcdir/build" NOT_CRAN=true Rscript --vanilla testthat.R
+}
+
+package() {
+  install -d "$pkgdir/usr/lib/R/library"
+  cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
+
+  install -d "$pkgdir/usr/share/licenses/$pkgname"
+  ln -s "/usr/lib/R/library/$_pkgname/LICENSE" "$pkgdir/usr/share/licenses/$pkgname"
+}

BioArchLinux/r-flowgate/lilac.py

@@ -0,0 +1,14 @@
+#!/usr/bin/env python3
+from lilaclib import *
+
+import os
+import sys
+sys.path.append(os.path.normpath(f'{__file__}/../../../lilac-extensions'))
+from lilac_r_utils import r_pre_build
+
+def pre_build():
+    r_pre_build(_G)
+
+def post_build():
+    git_pkgbuild_commit()
+    update_aur_repo()

BioArchLinux/r-flowgate/lilac.yaml

@@ -0,0 +1,23 @@
+build_prefix: extra-x86_64
+maintainers:
+- github: pekkarr
+  email: pekkarr@protonmail.com
+repo_depends:
+- r-biocmanager
+- r-dplyr
+- r-flowcore
+- r-flowworkspace
+- r-ggcyto
+- r-ggplot2
+- r-purrr
+- r-rlang
+- r-shiny
+- r-tibble
+repo_makedepends:
+- r-testthat
+update_on:
+- source: rpkgs
+  pkgname: flowGate
+  repo: bioc
+  md5: true
+- alias: r