r-rnetcdf: init, dependency of r-ncmeta, which is checkdependency of r-stars

BioArchLinux/r-rnetcdf/PKGBUILD

@@ -0,0 +1,40 @@
+# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
+
+_pkgname=RNetCDF
+_pkgver=2.6-2
+pkgname=r-${_pkgname,,}
+pkgver=${_pkgver//-/.}
+pkgrel=1
+pkgdesc="Interface to 'NetCDF' Datasets"
+arch=(x86_64)
+url="https://cran.r-project.org/package=${_pkgname}"
+license=(GPL)
+depends=(
+  netcdf
+  r
+  udunits
+)
+checkdepends=(
+  r-bit64
+)
+optdepends=(
+  r-bit64
+)
+source=("https://cran.r-project.org/src/contrib/${_pkgname}_${_pkgver}.tar.gz")
+md5sums=('faa65d9a33a7dd02fcf2a204d5c89819')
+sha256sums=('b4de45798fc5f3021f23187bc52d5931a86a4f5c91fcdba7ca4f92c966ec022e')
+
+build() {
+  mkdir -p build
+  R CMD INSTALL "$_pkgname" -l build
+}
+
+check() {
+  cd "$_pkgname/tests"
+  R_LIBS="$srcdir/build" Rscript --vanilla RNetCDF-test.R
+}
+
+package() {
+  install -d "$pkgdir/usr/lib/R/library"
+  cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
+}

BioArchLinux/r-rnetcdf/lilac.py

@@ -0,0 +1,18 @@
+#!/usr/bin/env python3
+from lilaclib import *
+
+import os
+import sys
+sys.path.append(os.path.normpath(f'{__file__}/../../../lilac-extensions'))
+from lilac_r_utils import r_pre_build
+
+def pre_build():
+    r_pre_build(
+        _G,
+        expect_license = "GPL (>= 2) | file LICENSE",
+        expect_systemrequirements = "netcdf udunits-2",
+    )
+
+def post_build():
+    git_pkgbuild_commit()
+    update_aur_repo()

BioArchLinux/r-rnetcdf/lilac.yaml

@@ -0,0 +1,18 @@
+build_prefix: extra-x86_64
+maintainers:
+- github: pekkarr
+  email: pekkarr@protonmail.com
+repo_depends:
+- udunits
+repo_makedepends:
+- r-bit64
+update_on:
+- source: rpkgs
+  pkgname: RNetCDF
+  repo: cran
+  md5: true
+- alias: r
+- source: alpmfiles
+  pkgname: netcdf
+  filename: usr/lib/libnetcdf\.so\.([^.]+)
+  repo: extra