r-bsgenomeforge: init

BioArchLinux/r-bsgenomeforge/PKGBUILD

@@ -0,0 +1,51 @@
+# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
+
+_pkgname=BSgenomeForge
+_pkgver=1.0.1
+pkgname=r-${_pkgname,,}
+pkgver=${_pkgver//-/.}
+pkgrel=1
+pkgdesc="Forge BSgenome data packages"
+arch=(any)
+url="https://bioconductor.org/packages/${_pkgname}"
+license=(Artistic2.0)
+depends=(
+  r-biobase
+  r-biocgenerics
+  r-biostrings
+  r-bsgenome
+  r-genomeinfodb
+  r-iranges
+  r-rtracklayer
+  r-s4vectors
+)
+checkdepends=(
+  r-testthat
+)
+optdepends=(
+  r-biocstyle
+  r-devtools
+  r-genomicfeatures
+  r-genomicranges
+  r-knitr
+  r-rmarkdown
+  r-testthat
+)
+source=("https://bioconductor.org/packages/release/bioc/src/contrib/${_pkgname}_${_pkgver}.tar.gz")
+md5sums=('630aec996209048e39553239dd20e563')
+sha256sums=('eb1afd85e3a0f97ae842e349e7ec972cd758bbf2a9a13cdde85b5a4a3232a232')
+
+build() {
+  mkdir -p build
+  R CMD INSTALL "$_pkgname" -l build
+}
+
+check() {
+  cd "$_pkgname/tests"
+  R_LIBS="$srcdir/build" NOT_CRAN=true Rscript --vanilla testthat.R
+}
+
+package() {
+  install -d "$pkgdir/usr/lib/R/library"
+  cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
+}

BioArchLinux/r-bsgenomeforge/lilac.py

@@ -0,0 +1,14 @@
+#!/usr/bin/env python3
+from lilaclib import *
+
+import os
+import sys
+sys.path.append(os.path.normpath(f'{__file__}/../../../lilac-extensions'))
+from lilac_r_utils import r_pre_build
+
+def pre_build():
+    r_pre_build(_G)
+
+def post_build():
+    git_pkgbuild_commit()
+    update_aur_repo()

BioArchLinux/r-bsgenomeforge/lilac.yaml

@@ -0,0 +1,21 @@
+build_prefix: extra-x86_64
+maintainers:
+- github: pekkarr
+  email: pekkarr@protonmail.com
+repo_depends:
+- r-biobase
+- r-biocgenerics
+- r-biostrings
+- r-bsgenome
+- r-genomeinfodb
+- r-iranges
+- r-rtracklayer
+- r-s4vectors
+repo_makedepends:
+- r-testthat
+update_on:
+- source: rpkgs
+  pkgname: BSgenomeForge
+  repo: bioc
+  md5: true
+- alias: r