mash: add ver 2.3

BioArchLinux/mash/PKGBUILD

@@ -0,0 +1,45 @@
+# Maintainer: Fabian Klötzl <fabian-aur@kloetzl.info>
+# Contributor: Bipin Kumar <kbipinkumar@pm.me>
+
+pkgname=mash
+pkgver=2.3
+pkgrel=1
+pkgdesc="Fast genome and metagenome distance estimation using MinHash"
+url="https://github.com/marbl/Mash/"
+license=("BSD")
+arch=("x86_64")
+depends=('gsl' 'glibc' 'zlib' 'gcc-libs')
+makedepends=("capnproto")
+source=("https://github.com/marbl/Mash/archive/v${pkgver}.tar.gz"
+		"dynamic-capnp.patch")
+sha256sums=('f96cf7305e010012c3debed966ac83ceecac0351dbbfeaa6cd7ad7f068d87fe1'
+            '61cd860e66e57f6cc3dac317cb19665263aaa1de9b8c487cb9133ccde2388d92')
+
+prepare() {
+	cd "Mash-${pkgver}"
+	patch -R -p1 -i ${srcdir}/dynamic-capnp.patch
+    sed -i 's|@prefix@|$(DESTDIR)@prefix@|g' Makefile.in
+    sed -i 's|-O3|-O2|g' Makefile.in
+    sed -i '41s/$(CXXFLAGS)/$(CXXFLAGS) $(LDFLAGS)/' Makefile.in
+    sed -i '11i#include <stdint.h>' src/mash/Command.cpp
+    sed -i '40i#include <limits>' src/mash/robin_hood.h
+}
+
+build() {
+	cd "Mash-${pkgver}"
+	autoconf
+	./configure --prefix="/usr" --with-capnp=/usr --with-gsl=/usr
+	make
+}
+
+check() {
+	cd "Mash-${pkgver}"
+	make test
+}
+
+package() {
+	cd "Mash-${pkgver}"
+    make DESTDIR="${pkgdir}" install
+    make DESTDIR="${pkgdir}" install-man
+    install -Dm0644 LICENSE.txt  "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+}

BioArchLinux/mash/dynamic-capnp.patch

@@ -0,0 +1,13 @@
+diff --git a/Makefile.in b/Makefile.in.old
+index 17f9515..146a9fc 100644
+--- a/Makefile.in
++++ b/Makefile.in
+@@ -36,7 +36,7 @@ OBJECTS=$(SOURCES:.cpp=.o) src/mash/capnp/MinHash.capnp.o
+ all : mash libmash.a
+ 
+ mash : libmash.a src/mash/memcpyWrap.o
+-	$(CXX) $(CXXFLAGS) $(CPPFLAGS) -o mash src/mash/memcpyWrap.o libmash.a @mathlib@ -lstdc++ -lz -lm -lpthread -lcapnp -lkj
++	$(CXX) $(CXXFLAGS) $(CPPFLAGS) -o mash src/mash/memcpyWrap.o libmash.a @capnp@/lib/libcapnp.a @capnp@/lib/libkj.a @mathlib@ -lstdc++ -lz -lm -lpthread
+ 
+ libmash.a : $(OBJECTS)
+ 	ar -cr libmash.a $(OBJECTS)

BioArchLinux/mash/lilac.yaml

@@ -0,0 +1,14 @@
+maintainers:
+  - github: kbipinkumar
+    email: kbipinkumar@pm.me
+build_prefix: extra-x86_64
+pre_build_script: |
+  update_pkgver_and_pkgrel(_G.newver.lstrip('v'))
+  run_cmd(['updpkgsums'])
+post_build_script: |
+  git_pkgbuild_commit()
+update_on:
+  - source: github
+    github: marbl/Mash
+    use_max_tag: true
+    prefix: 'v'