r-partcnv: init

BioArchLinux/r-partcnv/PKGBUILD

@@ -0,0 +1,48 @@
+# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
+
+_pkgname=partCNV
+_pkgver=1.0.0
+pkgname=r-${_pkgname,,}
+pkgver=${_pkgver//-/.}
+pkgrel=1
+pkgdesc="Infer locally aneuploid cells using single cell RNA-seq data"
+arch=(any)
+url="https://bioconductor.org/packages/${_pkgname}"
+license=(GPL2)
+depends=(
+  r-annotationhub
+  r-data.table
+  r-depmixs4
+  r-genomicranges
+  r-magrittr
+  r-seurat
+  r-singlecellexperiment
+)
+checkdepends=(
+  r-testthat
+)
+optdepends=(
+  r-biocstyle
+  r-iranges
+  r-knitr
+  r-rmarkdown
+  r-testthat
+)
+source=("https://bioconductor.org/packages/release/bioc/src/contrib/${_pkgname}_${_pkgver}.tar.gz")
+md5sums=('e004f2129cbb1fe1e84e33cf223c06f6')
+sha256sums=('4a948e65fe1f20118f9f5642e23fa35b92bfae680b5da1762084e88e187d8a95')
+
+build() {
+  mkdir -p build
+  R CMD INSTALL "$_pkgname" -l build
+}
+
+check() {
+  cd "$_pkgname/tests"
+  R_LIBS="$srcdir/build" NOT_CRAN=true Rscript --vanilla testthat.R
+}
+
+package() {
+  install -d "$pkgdir/usr/lib/R/library"
+  cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
+}

BioArchLinux/r-partcnv/lilac.py

@@ -0,0 +1,14 @@
+#!/usr/bin/env python3
+from lilaclib import *
+
+import os
+import sys
+sys.path.append(os.path.normpath(f'{__file__}/../../../lilac-extensions'))
+from lilac_r_utils import r_pre_build
+
+def pre_build():
+    r_pre_build(_G)
+
+def post_build():
+    git_pkgbuild_commit()
+    update_aur_repo()

BioArchLinux/r-partcnv/lilac.yaml

@@ -0,0 +1,20 @@
+build_prefix: extra-x86_64
+maintainers:
+- github: pekkarr
+  email: pekkarr@protonmail.com
+repo_depends:
+- r-annotationhub
+- r-data.table
+- r-depmixs4
+- r-genomicranges
+- r-magrittr
+- r-seurat
+- r-singlecellexperiment
+repo_makedepends:
+- r-testthat
+update_on:
+- source: rpkgs
+  pkgname: partCNV
+  repo: bioc
+  md5: true
+- alias: r