fiji: init, can't compile from source due to it's multi-pkgs

BioArchLinux/fiji/PKGBUILD

@@ -0,0 +1,40 @@
+#Maintainer: Franck Lominé <flomine@insa-rennes.fr>
+#Previous maintainer: Butui Hu <hot123tea123@gmail.com>
+#Previous maintainer: lilac <lilac@build.archlinuxcn.org>
+
+_pkgname=fiji
+pkgname=fiji
+pkgver=20240208.1017
+pkgrel=1
+epoch=2
+pkgdesc="ImageJ distribution with a lot of plugins for scientific (especially biology related) image processing."
+arch=('x86_64')
+url='http://fiji.sc/'
+license=('BSD-2-Clause')
+depends=(
+  'freetype2'
+  'libnet'
+)
+makedepends=('gendesk')
+
+source=("${pkgname}-${pkgver}.zip::https://downloads.imagej.net/fiji/archive/${pkgver/./-}/fiji-linux64.zip")
+sha256sums=('65951b121de3d663bd1546506e29373d57172dd42f2648aa1cfb532dd49acfb6')
+
+
+prepare() {
+  echo "Creating desktop file"
+  gendesk -f -n --pkgname ${_pkgname} \
+    --pkgdesc "${pkgdesc}" \
+    --categories "Graphics;Science;ImageProcessing;" \
+    --icon "${_pkgname}" \
+    --exec ${_pkgname}
+}
+
+package()
+{
+  install -d "${pkgdir}/opt" "${pkgdir}/usr/bin" "${pkgdir}/usr/share/pixmaps"
+  mv "${srcdir}/Fiji.app" "${pkgdir}/opt/${_pkgname}"
+  cp "${pkgdir}/opt/${_pkgname}/images/icon.png" "${pkgdir}/usr/share/pixmaps/${_pkgname}.png"
+  ln -s "/opt/${_pkgname}/ImageJ-linux64" "${pkgdir}/usr/bin/${_pkgname}"
+  install -Dm644 "${srcdir}/fiji.desktop" "${pkgdir}/usr/share/applications/fiji.desktop"
+}

BioArchLinux/fiji/lilac.yaml

@@ -0,0 +1,14 @@
+build_prefix: extra-x86_64
+maintainers:
+  - github: starsareintherose
+    email: kuoi@bioarchlinux.org
+pre_build_script: |
+  update_pkgver_and_pkgrel(_G.newver.lstrip('v'))
+post_build_script: |
+  git_pkgbuild_commit()
+update_on:
+  - source: regex
+    url: "http://www.clustal.org/download/current"
+    regex: '(\+d)-(\d+)/'
+    from_pattern: (\d+)-(\d+)/
+    to_pattern: \1\.\2