r-regionalpcs: init

BioArchLinux/r-regionalpcs/PKGBUILD

@@ -0,0 +1,53 @@
+# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
+
+_pkgname=regionalpcs
+_pkgver=1.0.0
+pkgname=r-${_pkgname,,}
+pkgver=${_pkgver//-/.}
+pkgrel=1
+pkgdesc="Summarizing Regional Methylation with Regional Principal Components Analysis"
+arch=(any)
+url="https://bioconductor.org/packages/${_pkgname}"
+license=(MIT)
+depends=(
+  r-dplyr
+  r-genomicranges
+  r-pcatools
+  r-tibble
+)
+checkdepends=(
+  r-rmtstat
+  r-testthat
+)
+optdepends=(
+  r-biocstyle
+  r-iranges
+  r-knitr
+  r-minfidata
+  r-rmarkdown
+  r-rmtstat
+  r-testthat
+  r-tidyr
+  r-txdb.hsapiens.ucsc.hg19.knowngene
+)
+source=("https://bioconductor.org/packages/release/bioc/src/contrib/${_pkgname}_${_pkgver}.tar.gz")
+md5sums=('37f0fc1370efacc719f72b419455096a')
+sha256sums=('e16add6355dc7e8f0abf1e64ebf7d630353fbe344029064834c5504ae6e9403d')
+
+build() {
+  mkdir -p build
+  R CMD INSTALL "$_pkgname" -l build
+}
+
+check() {
+  cd "$_pkgname/tests"
+  R_LIBS="$srcdir/build" NOT_CRAN=true Rscript --vanilla testthat.R
+}
+
+package() {
+  install -d "$pkgdir/usr/lib/R/library"
+  cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
+
+  install -d "$pkgdir/usr/share/licenses/$pkgname"
+  ln -s "/usr/lib/R/library/$_pkgname/LICENSE" "$pkgdir/usr/share/licenses/$pkgname"
+}

BioArchLinux/r-regionalpcs/lilac.py

@@ -0,0 +1,14 @@
+#!/usr/bin/env python3
+from lilaclib import *
+
+import os
+import sys
+sys.path.append(os.path.normpath(f'{__file__}/../../../lilac-extensions'))
+from lilac_r_utils import r_pre_build
+
+def pre_build():
+    r_pre_build(_G)
+
+def post_build():
+    git_pkgbuild_commit()
+    update_aur_repo()

BioArchLinux/r-regionalpcs/lilac.yaml

@@ -0,0 +1,18 @@
+build_prefix: extra-x86_64
+maintainers:
+- github: pekkarr
+  email: pekkarr@protonmail.com
+repo_depends:
+- r-dplyr
+- r-genomicranges
+- r-pcatools
+- r-tibble
+repo_makedepends:
+- r-rmtstat
+- r-testthat
+update_on:
+- source: rpkgs
+  pkgname: regionalpcs
+  repo: bioc
+  md5: true
+- alias: r