r-pkgsearch: init

BioArchLinux/r-pkgsearch/PKGBUILD

@@ -0,0 +1,56 @@
+# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
+# Contributor: peippo <christoph+aur@christophfink.com>
+
+_pkgname=pkgsearch
+_pkgver=3.1.3
+pkgname=r-${_pkgname,,}
+pkgver=${_pkgver//-/.}
+pkgrel=1
+pkgdesc="Search and Query CRAN R Packages"
+arch=(any)
+url="https://cran.r-project.org/package=$_pkgname"
+license=('MIT')
+depends=(
+  r-curl
+  r-jsonlite
+)
+checkdepends=(
+  r-mockery
+  r-pingr
+  r-testthat
+)
+optdepends=(
+  r-covr
+  r-memoise
+  r-mockery
+  r-pillar
+  r-pingr
+  r-rstudioapi
+  r-shiny
+  r-shinyjs
+  r-shinywidgets
+  r-testthat
+  r-whoami
+  r-withr
+)
+source=("https://cran.r-project.org/src/contrib/${_pkgname}_${_pkgver}.tar.gz")
+md5sums=('5506c33a6c44075c92b56d27eb68aabf')
+b2sums=('2021907562f44165304dbb762b6561e58d935f2d7c2822cec12545bf169a4379d49a76006aa65a64e2f164cadafb8120c9712813b8068b9f6c6a6de0fe9eaa6c')
+
+build() {
+  mkdir build
+  R CMD INSTALL -l build "$_pkgname"
+}
+
+check() {
+  cd "$_pkgname/tests"
+  R_LIBS="$srcdir/build" NOT_CRAN=true Rscript --vanilla testthat.R
+}
+
+package() {
+  install -d "$pkgdir/usr/lib/R/library"
+  cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
+
+  install -d "$pkgdir/usr/share/licenses/$pkgname"
+  ln -s "/usr/lib/R/library/$_pkgname/LICENSE" "$pkgdir/usr/share/licenses/$pkgname"
+}

BioArchLinux/r-pkgsearch/lilac.py

@@ -0,0 +1,13 @@
+#!/usr/bin/env python3
+from lilaclib import *
+
+import os
+import sys
+sys.path.append(os.path.normpath(f'{__file__}/../../../lilac-extensions'))
+from lilac_r_utils import r_pre_build
+
+def pre_build():
+    r_pre_build(_G)
+
+def post_build():
+    git_pkgbuild_commit()

BioArchLinux/r-pkgsearch/lilac.yaml

@@ -0,0 +1,17 @@
+build_prefix: extra-x86_64
+maintainers:
+- github: pekkarr
+  email: pekkarr@protonmail.com
+repo_depends:
+- r-curl
+- r-jsonlite
+repo_makedepends:
+- r-mockery
+- r-pingr
+- r-testthat
+update_on:
+- source: rpkgs
+  pkgname: pkgsearch
+  repo: cran
+  md5: true
+- alias: r