r-digest: use metadata checks

BioArchLinux/r-digest/PKGBUILD

@@ -1,33 +1,61 @@
-# Maintainer: Guoyi Zhang <guoyizhang at malacology dot net>
+# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
+# Contributor: Guoyi Zhang <guoyizhang at malacology dot net>
 # Contributor: Viktor Drobot (aka dviktor) linux776 [at] gmail [dot] com
 # Contributor: frichtlm <frichtlm@gmail.com>
 # Contributor: Grey Christoforo <first name at last name dot net>
+# Contributor: Alex Branham <alex.branham@gmail.com>
+# Contributor: Nick B <Shirakawasuna at gmail _dot_com>
+# Contributor: Francois Garillot <francois[@]garillot.net>
 
 _pkgname=digest
 _pkgver=0.6.33
 pkgname=r-${_pkgname,,}
-pkgver=0.6.33
+pkgver=${_pkgver//-/.}
 pkgrel=1
-pkgdesc='Create Compact Hash Digests of R Objects'
+pkgdesc="Create Compact Hash Digests of R Objects"
-arch=('x86_64')
+arch=(x86_64)
 url="https://cran.r-project.org/package=${_pkgname}"
-license=('GPL')
+license=(GPL)
 depends=(
+  google-crc32c
+  libblake3
   r
+  xxhash
+  zlib
+)
+checkdepends=(
+  r-tinytest
 )
 optdepends=(
   r-simplermarkdown
   r-tinytest
 )
 source=("https://cran.r-project.org/src/contrib/${_pkgname}_${_pkgver}.tar.gz")
+md5sums=('f47359e9e90e279714c9fd50a47ad2ed')
 sha256sums=('be702c886b1639be7eda4ea25a4261b30ce418c580f79bd78ec8d6cb4d327819')
 
+prepare() {
+  cd "$_pkgname/src"
+  # use system blake3, crc32c, xxhash and zlib
+  rm -r crc32c
+  rm blake3* crc32.* crc32c* xxhash.* z*
+  sed -i 's/digest_crc32/crc32/' digest.c
+  sed -e 's|PKG_CPPFLAGS = -I.|PKG_CPPFLAGS = -I/usr/include/crc32c -I.|' \
+      -e '2 a PKG_LIBS = -lblake3 -lcrc32c -lxxhash -lz' \
+      -i Makevars
+}
+
 build() {
-  R CMD INSTALL ${_pkgname}_${_pkgver}.tar.gz -l "${srcdir}"
+  mkdir -p build
+  R CMD INSTALL "$_pkgname" -l build
+}
+
+check() {
+  cd "$_pkgname/tests"
+  R_LIBS="$srcdir/build" Rscript --vanilla tinytest.R
 }
 
 package() {
-  install -dm0755 "${pkgdir}/usr/lib/R/library"
+  install -d "$pkgdir/usr/lib/R/library"
-  cp -a --no-preserve=ownership "${_pkgname}" "${pkgdir}/usr/lib/R/library"
+  cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
 }
-# vim:set ts=2 sw=2 et:

BioArchLinux/r-digest/lilac.py

@@ -1,12 +1,13 @@
 #!/usr/bin/env python3
 from lilaclib import *
 
+import os
+import sys
+sys.path.append(os.path.normpath(f'{__file__}/../../../lilac-extensions'))
+from lilac_r_utils import r_pre_build
+
 def pre_build():
-    for line in edit_file('PKGBUILD'):
+    r_pre_build(_G)
-        if line.startswith('_pkgver='):
-            line = f'_pkgver={_G.newver}'
-        print(line)
-    update_pkgver_and_pkgrel(_G.newver.replace(':', '.').replace('-', '.'))
 
 def post_build():
     git_pkgbuild_commit()

BioArchLinux/r-digest/lilac.yaml

@@ -1,9 +1,25 @@
 build_prefix: extra-x86_64
 maintainers:
-- github: starsareintherose
+- github: pekkarr
-  email: kuoi@bioarchlinux.org
+  email: pekkarr@protonmail.com
+repo_depends:
+- google-crc32c
+- libblake3
+repo_makedepends:
+- r-tinytest
 update_on:
-- regex: digest_([\d._-]+).tar.gz
+- source: rpkgs
-  source: regex
+  pkgname: digest
-  url: https://cran.r-project.org/package=digest
+  repo: cran
+  md5: true
 - alias: r
+- source: alpm
+  alpm: xxhash
+  repo: extra
+  provided: libxxhash.so
+  strip_release: true
+- source: alpm
+  alpm: zlib
+  repo: core
+  provided: libz.so
+  strip_release: true