r-ggtreedendro: init

BioArchLinux/r-ggtreedendro/PKGBUILD

@@ -0,0 +1,48 @@
+# Maintainer: Pekka Ristola <pekkarr [at] protonmail [dot] com>
+
+_pkgname=ggtreeDendro
+_pkgver=1.4.0
+pkgname=r-${_pkgname,,}
+pkgver=${_pkgver//-/.}
+pkgrel=1
+pkgdesc="Drawing 'dendrogram' using 'ggtree'"
+arch=(any)
+url="https://bioconductor.org/packages/${_pkgname}"
+license=(Artistic2.0)
+depends=(
+  r-ggplot2
+  r-ggtree
+  r-tidytree
+)
+checkdepends=(
+  r-testthat
+)
+optdepends=(
+  r-aplot
+  r-knitr
+  r-mdendro
+  r-prettydoc
+  r-pvclust
+  r-rmarkdown
+  r-testthat
+  r-treeio
+  r-yulab.utils
+)
+source=("https://bioconductor.org/packages/release/bioc/src/contrib/${_pkgname}_${_pkgver}.tar.gz")
+md5sums=('e5839d466e08665eb2475a99fb74e833')
+sha256sums=('ace77cc34d998168e516ef377b563d49d9d8895135fdc6cdb9359544f6b2df3e')
+
+build() {
+  mkdir -p build
+  R CMD INSTALL "$_pkgname" -l build
+}
+
+check() {
+  cd "$_pkgname/tests"
+  R_LIBS="$srcdir/build" NOT_CRAN=true Rscript --vanilla testthat.R
+}
+
+package() {
+  install -d "$pkgdir/usr/lib/R/library"
+  cp -a --no-preserve=ownership "build/$_pkgname" "$pkgdir/usr/lib/R/library"
+}

BioArchLinux/r-ggtreedendro/lilac.py

@@ -0,0 +1,14 @@
+#!/usr/bin/env python3
+from lilaclib import *
+
+import os
+import sys
+sys.path.append(os.path.normpath(f'{__file__}/../../../lilac-extensions'))
+from lilac_r_utils import r_pre_build
+
+def pre_build():
+    r_pre_build(_G)
+
+def post_build():
+    git_pkgbuild_commit()
+    update_aur_repo()

BioArchLinux/r-ggtreedendro/lilac.yaml

@@ -0,0 +1,16 @@
+build_prefix: extra-x86_64
+maintainers:
+- github: pekkarr
+  email: pekkarr@protonmail.com
+repo_depends:
+- r-ggplot2
+- r-ggtree
+- r-tidytree
+repo_makedepends:
+- r-testthat
+update_on:
+- source: rpkgs
+  pkgname: ggtreeDendro
+  repo: bioc
+  md5: true
+- alias: r